The curse of Dennis D. Spreen

Pass a multidimensional array as a parameter (with a hidden caveat)

How to pass a multidimensional array as a parameter? Long ago this question was answered on Stack Overflow with a simple answer: make a specific type for your array. But there is a hidden caveat…

If you need to pass a multidimensional array as a parameter you’d probably type this

procedure DoSomething(MyParameter: array of array of Integer);

however the above code won’t compile (‘E2029 Identifier expected but ARRAY found’). By declaring a specific type for the array it compiles:

type
  TMyArray = array of array of Integer;

procedure DoSomething(MyParameter: TMyArray);

Looks nice, but there is something nasty hidden in there. But let’s take a step back – how about changing your one dimensional array procedures the same way? Your procedure may look like

procedure DoSomething(MyParameter: array of Integer);

but surely is a lot better to read by declaring an integer array type before:

type
  TIntegerArray = array of Integer;

procedure DoSomething(MyParameter: TIntegerArray);

Are both the same? No, they aren’t. Let’s prove it with a little bit of more code:

type
  TIntegerArray = array of Integer;

procedure Inc1(Data: array of Integer);
begin
  Data[0] := Data[0] + 5;
end;

procedure Inc2(Data: TIntegerArray);
begin
  Data[0] := Data[0] + 5;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  Data1: TIntegerArray;
begin
  SetLength(Data1, 1);

  Data1[0] := 1;
  Inc1(Data1);
  Memo1.Lines.Add(Data1[0].toString);

  Data1[0] := 1;
  Inc2(Data1);
  Memo1.Lines.Add(Data1[0].toString);
end;

At first a dynamic array with a size of 1 is created and before the two Inc’s are called it is filled with 1 – as both procedures uses the array passed as a value, both lines should still read “1” afterwards. But the second memo line shows a “6“ – this call is a call by reference!

Adding a const or var doesn’t change anything – the dynamic array is always passed as a reference if declared as a type!

What about the nextgen (iOS/Android) compiler? It’s the same, so be careful by replacing dynamic array parameters by array types – you always end up passing them by reference!

 

 

Tags: Delphi Programming

4 Comments to Pass a multidimensional array as a parameter (with a hidden caveat)

Leave a comment